Re^2: How many loops are there in Perl?

[AnomalousMonk]

... the naked-block isn't a loop ... without a label and goto[.]

Or at least a (possibly conditional) redo (see also Loop Control):

perl -wMstrict -le
"my $i = 1;  { print qq{in naked loop $i};  redo if $i++ < 3; }
"
in naked loop 1
in naked loop 2
in naked loop 3

[adamcrussell]

I have always thought redo was cool. At first glance it doesn't look anything like a goto because it is usually used with bare blocks. The code below has redo going to the start of the nearest enclosing block.

{
    print "Enter a number 0-9\n";
    $number=<STDIN>;
    chomp($number);
    unless(length($number) == 1  && $number =~ /[0-9]/){
        print "C'mon, man! give me a number 0-9!\n";  
        redo;  
    }
}

However, redo can take an argument (a block label) which makes it look much more goto-ish and less like elegant Perl. For example, we could redo (pun intended!) the example like this:

GET_NUMBER:{
    print "Enter a number 0-9\n";
    $number=<STDIN>;
    chomp($number);
    unless(length($number) == 1  && $number =~ /[0-9]/){
        print "C'mon, man! give me a number 0-9!\n";  
        redo GET_NUMBER;  
    }
}

The biggest difference between redo and a pure goto is that redo must go to an enclosing block label whereas goto goes to any label. This is still a valid redo:

my $number;  

PROMPT_FOR_NUMBER:{
        print "Enter a number 0-9\n";
        GET_NUMBER:{
            $number=<STDIN>;
            chomp($number);
            unless(length($number) ==1  && $number =~ /[0-9]/){
                print "You don't want to give me one number ?\n";  
                redo PROMPT_FOR_NUMBER;
            }
        } 
}