Re: Regex in json: escaping forward slash

[Mr. Muskrat]

How about you show us the code you're using to read that JSON? Then we can tell you how to make it work properly.

[mhearse]

#!/usr/bin/env perl

use strict;
use JSON;
use Data::Dumper;

my $contents = `cat progconfig.json`;
my $config = JSON->new->decode($contents);

print Dumper($config);

[davido]

But what's the problem? Maybe you could provide an example of how your code is failing to deal with '/' properly. In the following example I decode your sample JSON, grab the key that looks like a regular expression, compile it as a regular expression, and use it to perform a match.

use strict;
use warnings;
use JSON;

use constant KEY   => 0;
use constant VALUE => 1;

my $json_string = <<'END_JSON';
{
  "regex" : {
    ".*/home/members/index.htm.*" : {
      "404" : {
        "reporting" : "1000",
        "paging" : "2000"
      }
    }
  }
}
END_JSON

my @test_strings  = qw( 
  web/home/members/index.htm?garbage=bye
  /home/memberzzzz/index.htm?garbage=bye
);

my $decoded_json = JSON->new->decode( $json_string );

# The regex is contained within a hash key.
my $regex_string = (%{$decoded_json->{regex}})[KEY]; 

my $regex        = qr/$regex_string/;

foreach my $test_string ( @test_strings ) {
  if( $test_string =~ m/$regex/ ) {
    print "Bingo! [$test_string] matches the pattern '$regex_string'\n
+";
  }
  else {
    print "Boo! [$test_string] doesn't match the pattern '$regex_strin
+g'\n";
  }
}

No special escaping of '/' here. The qr// operator is convenient.

[mhearse]

Thanks for your reply. I made a poor assumption. I was under the impression that:

my $regex = ".*/home/members/index.htm.*";
if (/$regex/)

Was the same as

if (/.*/home/members/index.htm.*/)

Which would fail. I was wrong!

[Mr. Muskrat]

That code doesn't exhibit the problem you are trying to solve. (It isn't trying to do anything that requires escaping the slashes.)

Output:

$VAR1 = {
          'regex' => {
                       '.*/home/members/index.htm.*' => {
                                                          '404' => {
                                                                     '
+reporting' => '1000',
                                                                     '
+paging' => '2000'
                                                                   }
                                                        }
                     }
        };

Even when I use that key as a regex, it works for me.

#!/usr/bin/env perl
use strict;
use warnings;
use JSON;
use Data::Dumper;

my $contents = `cat progconfig.json`;
my $config = JSON->new->decode($contents);

my $re = (keys %{$config->{regex}})[0];
print "re: $re\n";
my $path = '/some/fake/path/home/members/index.html';
if ( $path =~ /$re/ )
{
    print "$path matched regex\n";
}

Output:

re: .*/home/members/index.htm.*
/some/fake/path/home/members/index.html matched regex