#!/usr/local/bin/perl
# mailwormkiller.pl
# (c) Bart Lateur 20/21 sept 2003
# This is free software. Just don't pretend YOU wrote it!
# framework based on example 8.1 of Lincoln Stein's book,
# "Network Programming with Perl"
# Edit these to your personal settings:
my($host, $login, $passwd) = qw(mailhost.mydomain.com mylogin mypassword);

use strict;
use Net::POP3;
use Mail::Header;

my $pop = Net::POP3->new($host, Timeout=>30) or die "Can't connect to $host: $!\n";
my $messages = $pop->login($login => $passwd)  or die "Can't log in: ", $pop->message,"\n";

printf "Check at %s\n", scalar localtime;
my $delcount = 0;
if($messages += 0) {
    printf "Inbox holds %d message%s\n", $messages, $messages!=1 && 's';

    for my $msgnum (1 .. $messages) {
        my $header = $pop->top($msgnum, my $linecount = 40);
        my $parsedhead = Mail::Header->new($header);
        chomp(my $subject = $parsedhead->get('Subject'));
        chomp(my $from = $parsedhead->get('From'));

        my $deleted = 0;
        my $offset = '';
        if($parsedhead->get('Mime-Version')) {
            my $redone;
            {
                local $_ = join "", @$header;
                tr/\r//d;
                s/^(.+\n)+\n+//;
                (undef, $deleted) = m[^--.*\n
                  (?:(?:Content|[\t\ ]).+\n)*
                  Content-(?:Type:\s+\w*/[\w\-]+;\s+
                   |Disposition:\s+\w+;\s+file)
                  name=("?).*\.(exe|scr|pif|com|dll|bat|cpl)\1$]xmi
                  and $offset = substr($_, 0, $+[0]) =~ tr/\n//;
                # for earlier perls you can get along (with slightly different results) by using:
                # $offset = $` =~ tr/\n//;
                last if $deleted || $redone++ || tr/\n// < $linecount;
                $header = $pop->top($msgnum, $linecount = 700);
                redo;
            }
        }
        if($deleted) {
            $pop->delete($msgnum);
            $delcount++;
        }
        printf "%3d %-3s %3s %-25s  %s\n", $msgnum, $deleted || 'ok', $offset, $from, $subject;
    }
    printf "%d message%s deleted.\n\n", $delcount, $delcount!=1 && 's';
} else {
    printf "%s\n\n", "You don't have pending mail.";
}
$pop->quit;