Re: threads: work crew memory leak

[BrowserUk]

1. On Vista 64-bit / perl 5.10.1 / threads v1.76 / threads::shared v1.33 I see no signs of a memory leak.

   What versions of those modules do you have?

2. Having run for 100,000+ thread creation/deleteion cycles, the memory usage wobbles a bit but stays pretty much fixed around 35 or 35 MB mark. The occasional spikes just mean that at the instance that value was taken more threads had been created than destroyed in the last second or two. A situation that corrects itself immediately.

   An app that creates 100,000 threads in 15 minutes, each to handle 1 number, is really badly designed. Like building a new train for every journey to work. Inefficient and unsustainable.

3. All your shenanigans with a semaphore and detach and is_detached() are utterly redundant.

   Once you detach the thread, it ends. There is no possibility of attempting to "do it twice". And if you did attempt to detach the same thread twice, it does do no harm at all.

   This code functions identically with more clarity:

   #!/usr/bin/perl
   use strict;
   use warnings;
   use threads;
   use threads::shared;
   use Data::Dumper;
   
   $|=1;
   
   my $MAX_THREADS = 20;
   my $TERM :shared = 0;
   
   $SIG{'INT'} = $SIG{'TERM'} = sub {
           print("^C captured\n");
           $TERM=1;
   };
   
   sub stuff_thr($) {
       my ($job)=@_;
       my $tid=threads->tid();
   
       print "Hi, I am thread: $tid, I need to do something with $job\n";
   }
   
   sub main() {
       my @jobs = ( 1 .. 100 );
       
       while (@jobs && ! $TERM) {
   
           for( 1 .. $MAX_THREADS - threads->list() ) {
               my $job = shift(@jobs);
               last if (! $job);
   
               threads->create('stuff_thr',$job)->detach;
           }
   
           @jobs = ( 1 .. 100 ) if @jobs < 10
       }
       sleep 1 while threads->list() > 0;
   }
   
   main();