Variable as name of array

[Hopfi]

Hi there! Was wondering if you can create arrays with the name of another variable. I dont know how to explain it better. Heres an example:

my @names = qw(A B C D);
for(my $i=0; $i<4; $i++) {
    my @$names[$i] = ($i);
}

Any idea if thats possible? Cheers

[bart]

So nobody mentioned this yet? Well, I will.

Why it's stupid to use a variable as a variable name (3 part post by M.J.Dominus; a classic)

[sundialsvc4]

Hastening to ++ this.   The Perl variable-names namespace is not intended to be a hash.   The best part of this series is definitely part-3.

[fishmonger]

What you're asking about is called a symbolic reference and you want to stay far far away from them. Instead use a hash.

Perl Style: Avoid Symbolic References http://www.perl.com/doc/FMTEYEWTK/style/slide24.html

[Hopfi]

Ah ok thanks! So IŽd do something like:

my @names = qw(A B C D);
my %order = ();
for(my $i=0; $i<4; $i++) {
    $order{$names[$i]} = $names[$i];
}

while ((my $key, my $value) = each(%order)){
     print $key.", ".$value."\n";
}

Right?

[johngg]

Yes, you could do that but a Perl-style loop (see Foreach Loops) might be more idiomatic than a C-style one (For Loops). In fact, for and foreach are synonymous and can both be used interchangeably for either style of loop.

$ perl -Mstrict -Mwarnings -MData::Dumper -E '
> my @names = qw{ A B C D };
> my %order;
> foreach my $name ( @names )
> {
>     $order{ $name } = $name;
> }
> print Data::Dumper->Dumpxs( [ \ %order ], [ qw{ *order } ] );'
%order = (
           'A' => 'A',
           'D' => 'D',
           'C' => 'C',
           'B' => 'B'
         );
$

Another way to construct the hash would be to use a map instead of the foreach.

$ perl -Mstrict -Mwarnings -MData::Dumper -E '
> my @names = qw{ A B C D };
> my %order = map { $_ => $_ } @names;
> print Data::Dumper->Dumpxs( [ \ %order ], [ qw{ *order } ] );'
%order = (
           'A' => 'A',
           'D' => 'D',
           'C' => 'C',
           'B' => 'B'
         );
$

I hope this is helpful.

[tobyink]

Have you tried? You need some extra braces in there, and need to drop the second my, but other than that your code works...

my @names = qw(A B C D);
for (my $i=0; $i<4; $i++) {
   @{$names[$i]} = $i;
}

use Data::Dumper;
print Dumper(\@A, \@B, \@C, \@D);

These are called symbolic references. It is forbidden by the strict parameter because it's usually a bad idea. That's not to say it's always a bad idea; strict refs is just about the only part of strict that's occasionally worth disabling (occasionally, in a small lexical scope).

There are usually better ways of doing it. Here's one way, using a hash of arrays:

use strict;

my %ARRAYS;
my @names = qw(A B C D);
for (my $i=0; $i<4; $i++) {
   @{ $ARRAYS{$names[$i]} } = $i;
}

use Data::Dumper;
print Dumper(@ARRAYS{@names});

Here's another way using hard references instead of symbolic references:

use strict;

my (@A, @B, @C, @D);
my @names = (\@A, \@B, \@C, \@D);
for (my $i=0; $i<4; $i++) {
   @{$names[$i]} = $i;
}

use Data::Dumper;
print Dumper(\@A, \@B, \@C, \@D);

[toolic]

perldoc -q variable

How can I use a variable as a variable name?