Need Help With Alarm And Eval

[PerlRocks6345]

Hi Monks the code below works perfectly

 use strict;
 my $errorName="alarm\n";
 my $time=5;

    eval {
        local $SIG{ALRM} = sub { die "$errorName" };
        alarm $time;
       
        
        sleep(10); 
        
    };
    my $error= $@;
    
    Off($error,$errorName);
    
    sub Off{
    my $error=$_[0];
    my $errorName=$_[1];
  if( $error && $error eq "$errorName") 
  {
   warn "Timed out!!!\n"; 
   
    exit ;
    }
    else 
    {
    alarm 0;
    print " you can continue";
    }
}

But when I make it to subroutines as this

 use strict;
 my $errorName="alarm\n";
 my $time=5;
    
    eval {
    On($time,$errorName);
        
        #dostuff();
        
        sleep(10); 
    };
    my $error= $@;
    print "error ".$error."error \n";
    Off($error,$errorName);
    
sub On
{
    my $time=$_[0];
    my $errorName=$_[1];
        local $SIG{ALRM} = sub { die "$errorName" };
        alarm $time;
}
    
    
sub Off
{
    my $error=$_[0];
    my $errorName=$_[1];
    if( $error && $error eq "$errorName") 
        {
            warn "Timed out!!!\n"; 
            
            exit ;
        }
    else 
        {
            alarm 0;
            print " you can continue";
        }
}

It does not work as expected instead of throwing the warning message it throws "Terminating on signal SIGALRM(14)" Need your help Monks.Thank you in advance

[afoken]

The problem is local inside sub On. Perl restores $SIG{'ALRM'} as soon as On returns. You have no other handler for that signal, so the default handler kicks in and kills perl.

Alexander

[PerlRocks6345]

Hey thanks a lot for your reply removed local and every thing worked perfectly!!!! Thanks a lot!!!!!

[afoken]

removed local and every thing worked perfectly

No, it doesn't. The On function sets the signal handler globally, for ever, even after eval has finished. You want local $SIG{'ALRM'} inside that eval.

The extra subs don't make your code any clearer. I think you should keep alarm and local $SIG{'ALRM'} inside the eval.

You could also consider writing a generic timeout function like this:

# untested

sub withTimeout
{
    my ($timeout,$worker,$timeouthandler)=@_;
    eval {
        local $SIG{'ALRM'}=sub { die "TIMEOUT" };
        alarm($timeout);
        $worker->();
        alarm(0);
    };
    if ($@ and $@=~/TIMEOUT/) {
        $timeouthandler->();
    }
}

Alexander