Why is the error thrown from close(FH) when the error is the missing <> on while(FH)?

[techgrrl]

Greetings fellow monks.

I solved my problem, but I am trying to understand the error message that preceded it, that I might gain wisdom from the experience.

When I leave off the <> operator on the while(<KNOWN_HOSTS> loop on line 83 in the below code snippet, the error is thrown from the close on line 92, instead of the while on line 83.

My question is: Why is the error not thrown from the while on 83?

while (KNOWN_HOSTS) {   # this is line 83
    $inline = $_;
    if (isOneOf($inline,@contexts)) {
        next;
    } else {
        print;
    }
}

close(KNOWN_HOSTS);  # this is line 92

user@localhost ~$ ./strip_keys.pl -u user my-device.config
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at ./strip_keys.pl line 92.
Execution of ./strip_keys.pl aborted due to compilation errors.

[kcott]

G'day techgrrl,

Welcome to the monastery.

Perl is reading up to the statement terminator (semicolon) on line 92 before deciding that it's found a disallowed bareword. The fact that line 92 also contains KNOWN_HOSTS is something of a red herring. Consider:

$ perl -Mstrict -E '
    while (KNOWN_HOSTS) {
        say "Hello";
        last;
    }
    close KNOWN_HOSTS;
'
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at -e li
+ne 6.
Execution of -e aborted due to compilation errors.

versus

$ perl -Mstrict -E '
    while (KNOWN_HOSTS) {
        say "Hello";
        last;
    }
    say "Bye";
'
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at -e li
+ne 6.
Execution of -e aborted due to compilation errors.

Where code extends over multiple lines, Perl will typically report an error at the end of the multi-line code. You need to bear this in mind when debugging - you can have instances where you need to backtrack many lines to find the line where the actual problem has occurred.

If you're wondering why Perl didn't see the closing brace as the end of the statement, consider:

$ perl -Mstrict -E '
    while (KNOWN_HOSTS) {
        say "Hello";
        last;
    }
    continue {
        1;
    }
'
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at -e li
+ne 8.
Execution of -e aborted due to compilation errors.

Aside: where you used perl -MO=Deparse -p ... above, I'm wondering if you meant perl -MO=Deparse,-p ..., i.e. s/ -p/,-p/.

[techgrrl]

Thank you Ken!

That was the source of my confusion. To summarize the answer: PERL reports multi-line errors at the end, and the close(FH) at the end of the piece of code was a red-herring.

That was not behavior I was expecting.

Have a great day!

TechGrrl

[toolic]

Tip #6 from the Basic debugging checklist: B::Deparse can shed some light:

while (1) {
    $inline = $_;
    if (isOneOf($inline, @contexts)) {
        next;
    }
    else {
        print $_;
    }
}
close KNOWN_HOSTS;

[techgrrl]

Thanks, but do bear in mind, I already know the error, and I fixed it.

This question has nothing to do with the syntax error, it is about trying to understand a diagnostic message, in order to gain wisdom.

I ran deparse, and it printed my code prepended with the word LINE: and followed it with a diagnostic saying the syntax was OK.

$ perl -MO=Deparse -p strip_keys.pl 

LINE: while (defined($_ = <ARGV>)) {
    use warnings;
    use strict 'refs';
    our($opt_h, $opt_k, $opt_u);
    my($inline, $device, $config, $file, $context, @contexts);
    use Getopt::Long;
    &help unless GetOptions 'h', \$opt_h, 'u:s', \$opt_u, 'k:s', \$opt
+_k, 'device:s', \$device;
    &help if $opt_h;
   etc.

continue {
    print $_;
}

strip_keys.pl syntax OK

[Anonymous Monk]

My question is: Why is the error not thrown from the while on 83?

It is, it just doesn't say line 83, the line number is wrong, it is a mismatch, example

$ cat junk
while( STDIN ){
    @ARGV=2;
}
# 4
# 5
$ perl -w -Mstrict junk
Bareword "STDIN" not allowed while "strict subs" in use at junk line 5
+.
Execution of junk aborted due to compilation errors.

$ cat junk
while( STDIN ){
    @ARGV=2;
}

I vaguely remember when I first learned to always look at the earliest error message, start at the reported line number, and look before, look above -- this is especially true in perl :)

But you've found a new bug in strict.pm, consider

 $ cat junk
while( STDIN ){
    @ARGV=2;
}
close STDIN;

With strict the following error message is misleading

$ perl -Mstrict junk
Bareword "STDIN" not allowed while "strict subs" in use at junk line 4
+.
Execution of junk aborted due to compilation errors.

If you look at line 4, you'll see  close STDIN, but we know close takes barewords -- it can be very confusing even if you know to look above

But with warnings the error message is more informative

$ perl -w junk
Bareword found in conditional at junk line 4.
Terminating on signal SIGINT(2)

Sure, the line number is wrong (and the program runs forever, infinite loop is infinite), but we know  close STDIN; is not a conditional , so there is less confusion

OTOH :) here is where the advantage falls apart , a conditional  close STDIN if fileno STDIN; or  fileno STDIN and close STDIN;

so warnings can detect a bareword in a conditional, strict can name the bareword, strict should say it is in a conditional, its more informative

On the history of the line number bug
Warning gets the line number wrong?
Error messages point to wrong line number in if-elsif construct,
if-elsif weirdness,
No Pause on Elsif in Debugger
https://rt.perl.org/rt3//Public/Search/Simple.html?q=perl5+line+number
#1031: Incorrect line number reporting due to overoptimization
#1034: error line number reported wrong when using here documents
#7084: "Use of uninitialized value" reported on incorrect line number
#8051: -B wrong line number after die
#47632: Undef loop while condition, loop code motion, and bad warning line number? 5.10-RC1 + 5.8.8
#70910: wrong line number in syntax error message
#114070: here-docs cause bogus line numbers
#115768: wrong line number in error message

:) Perl gets the line number right in the beginning (: (see "junk:" below)

$ cat junk
while( STDIN ){
    @ARGV=@ARGV;
}
close STDIN ;
$ perl -MO=Concise junk
h  <@> leave[1 ref] vKP/REFC ->(end)
1     <0> enter ->2
2     <;> nextstate(main 3 junk:1) v:{ ->3
d     <2> leaveloop vK/2 ->e
3        <{> enterloop(next->c last->d redo->4) v ->4
-        <@> lineseq vK ->d
4           <;> nextstate(main 1 junk:2) v ->5
b           <2> aassign[t6] vKS/COMMON ->c
-              <1> ex-list lK ->8
5                 <0> pushmark s ->6
7                 <1> rv2av[t5] lK/1 ->8
6                    <#> gv[*ARGV] s ->7
-              <1> ex-list lK ->b
8                 <0> pushmark s ->9
a                 <1> rv2av[t3] lKRM*/1 ->b
9                    <#> gv[*ARGV] s ->a
c           <0> unstack v ->4
e     <;> nextstate(main 3 junk:4) v:{ ->f
g     <1> close vK/1 ->h
f        <#> gv[*STDIN] s ->g
junk syntax OK

update: :) I acknowledge kcott beat me to the punch , I mean he struck first, I mean I'm not a violent person at all, its just an expression, he posted first :p

[techgrrl]

Those are some great links! The first one has some good examples of this occurring in other contexts. I have a lot of reading to do.

Thanks for taking the time to include those references!

TechGrrl

[Anonymous Monk]

Given the the file handle is actually is, error is coming from the condition for while ...

#  cat p.pl ; perl p.pl

use strict;

open FH , '<' , $0 or die "open failed: $!";

while( FH )
{
  last;
}

close FH or die "close failed: $!";

__END__

Bareword "FH" not allowed while "strict subs" in use at p.pl line 11.
Execution of p.pl aborted due to compilation errors

... despite the line number reported. open & close can deal with a bareword file handle but not loop condition.

[7stud]

How did you get that far:

Global symbol "$inline" requires explicit package name at 2.pl line 6.
Global symbol "$inline" requires explicit package name at 2.pl line 7.
Global symbol "@contexts" requires explicit package name at 2.pl line 
+7.
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at 2.pl 
+line 14.
Execution of 2.pl aborted due to compilation errors.

Next, is it your understanding that a while loop conditional can only be the line input operator(<>)?

[techgrrl]

Greetings

It is a code fragment, not a full program.

In order to actually create an executable script I would need to provide multiple files and quite a bit more code. I can do that if requested, but I was hoping that since the reason the error was thrown was given (the missing double diamond <> operator) that someone could look at this and help me understand why is was thrown from the close(FH) instead of the while(FH) where the error is.

I don't think duplicating the error would tell you anything the sample does not already tell you, but I could be wrong I suppose.

Cheers,

TechGrrl

[7stud]

This doesn't produce an error:

my $fname = 'data.txt';

open FH, "<", $fname
    or die "Couldn't open $fname: $!";

while(FH) {
    print "hello\n";
}

Nor does this:

while(FH) {
    print "hello\n";
}

According to "Perl Best Practices", p. 65:

In Perl, any identifier that the compiler doesn't recognize as a subroutine (or as package name or filehandle or label or builtin function) is treated as an unquoted character string:

$greeting = Hello . World;
print $greeting, "\n";           #Prints: HelloWorld

I'm not sure why there are parentheses around "or package name or filehandle..." because the section is not about subroutines. And it should say, "...is treated as a string".

[parv]

You missed to read the error message in OP, repeated below for you, that has the clue ...

user@localhost ~$ ./strip_keys.pl -u user my-device.config
Bareword "KNOWN_HOSTS" not allowed while "strict subs" in use at ./str
+ip_keys.pl line 92.
Execution of ./strip_keys.pl aborted due to compilation errors.

... run your own 1st snippet of code with "use strict;" and be able to reproduce the fatal error similar to above. Also, read up on "constant" pragma and "bareword".

[7stud]

No, I saw it eventually--I was still editing my post when you posted. :)