Time for you to learn OOP!
{
package Person;
use Moo;
has name => (is => 'ro', required => 1);
has age => (is => 'rw', required => 1);
sub introduce_yourself {
my $self = shift;
printf("My name is %s, and I am %d years old.\n", $self->name,
+ $self->age);
}
}
my $alice = Person->new(name => 'Alice', age => 32);
$alice->introduce_yourself;
Note that we don't need to pass any $name and $age variables to introduce_yourself. It picks them up automatically from the $self object.
And because we've not used any globals, we can easily have two people living side by side. They each get their own copy of name and age and don't get them mixed up:
my $alice = Person->new(name => 'Alice', age => 32);
my $bob = Person->new(name => 'Bob', age => 31);
$_->introduce_yourself for $alice, $bob;
When two people are living side by side, they don't always remain just two people. Let's extend Person with the ability to breed more people...
{
package Person;
use Moo;
has name => (is => 'ro', required => 1);
has age => (is => 'rw', required => 1);
sub introduce_yourself {
my $self = shift;
printf("My name is %s, and I am %d years old.\n", $self->name,
+ $self->age);
}
}
{
package Breeding;
use Moo::Role;
has children => (is => 'ro', default => sub { return []; });
sub is_parent {
my $self = shift;
@{ $self->children };
}
sub bear_children {
my $self = shift;
my ($partner, @kids_names) = @_;
for my $name (@kids_names) {
my $kid = ref($self)->new(name => $name, age => 0);
push @{ $self->children }, $kid;
push @{ $partner->children }, $kid;
}
return;
}
}
{
package Person::Breeding;
use Moo;
extends 'Person';
with 'Breeding';
}
my $alice = Person::Breeding->new(name => 'Alice', age => 32);
my $bob = Person::Breeding->new(name => 'Bob', age => 31);
$_->introduce_yourself for $alice, $bob;
$alice->bear_children($bob, 'Carol', 'Dave', 'Eve');
print "Bob is a father!\n" if $bob->is_parent;
PS: in the interest of pimping my new project Moops, here's that last example again, using Moops instead of plain Moo:
use Moops;
class Person {
has name => (is => 'ro', required => 1);
has age => (is => 'rw', required => 1);
method introduce_yourself () {
printf("My name is %s, and I am %d years old.\n", $self->name,
+ $self->age);
}
}
role Breeding {
has children => (is => 'ro', default => sub { return []; });
method is_parent () {
@{ $self->children };
}
method bear_children ($partner, @kids_names) {
for my $name (@kids_names) {
my $kid = ref($self)->new(name => $name, age => 0);
push @{ $self->children }, $kid;
push @{ $partner->children }, $kid;
}
return;
}
}
class Person::Breeding extends Person with Breeding;
my $alice = Person::Breeding->new(name => 'Alice', age => 32);
my $bob = Person::Breeding->new(name => 'Bob', age => 31);
$_->introduce_yourself for $alice, $bob;
$alice->bear_children($bob, 'Carol', 'Dave', 'Eve');
say "Bob is a father!" if $bob->is_parent;
use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name