Regex question - identify which pattern comes first

[harangzsolt33]

I feel like I have learned a lot in the past 10 years since I started learning Perl, but I still probably don't know more than half of what's possible using regex. I have often come across situations where I needed to identify which pattern occurs first in a string. So, I am not trying to capture a part of the pattern nor am I trying to identify if it occurs at all or where. I am just trying to figure our which of the possible patterns is FIRST in the string. For example:

Sample string: "AB ABDA DCACCB AAA BSAA CAAB ACS ABA DBA BA DASSABACA A"

I'm looking for either: BA[ABC]{2} OR CA[CD]{2} OR DA[SC]{2}

So, I would write: /BA[ABC]{2}|CA[CD]{2}|DA[SC]{2}/

Is there a way to get a return value of 1, 2, or 3 depending on which pattern was matched first? How would I do that?

[ikegami]

if ( /(BA[ABC]{2})|(CA[CD]{2})|(DA[SC]{2})/ ) {
   my $first =
     ( defined( $1 ) ? 1
     : defined( $2 ) ? 2
     :                 3
     );

   ...
}

local our $first;

/
   (?: BA[ABC]{2} (?{ $first = 1; })
   |   CA[CD]{2}  (?{ $first = 2; })
   |   DA[SC]{2}  (?{ $first = 3; })
/x;

Update: I had mixed up (??{ }) and (?{ }). Fixed.

[harangzsolt33]

Oh wow, that is an amazingly simple solution! Thank you so much!!! :-)

[LanX]

> that is an amazingly simple solution!

Did you try it?

These (??{ $first = 1; }) won't work because they'll include 1,2 or 3 into the regex.

Try (?{ $first = 1; }); with a single ? instead.

Thus

[LanX]

requires 5.10 for named capture groups:

This code will even give you the sequence.

use v5.10;
use strict;
use warnings;

my $str = "AB ABDA DCACCB AAA BSAA CAAB ACS ABA DBA BA DASSABACA A";


while ( $str =~ / (?<_1> BA[ABC]{2} ) | (?<_2> CA[CD]{2} ) | (?<_3> DA
+[SC]{2} ) /gx) {
    print keys %+, " => ", values %+, " at pos ", pos($str), " \n";
}

_2 => CACC at pos 13 
_3 => DASS at pos 48 
_1 => BACA at pos 53

edit

• inserted /x for readability

[ikegami]

Adjusted for OP:

if (
   $str =~ /
      (?: (?<_1> BA[ABC]{2} )
      |   (?<_2> CA[CD]{2} )
      |   (?<_3> DA[SC]{2} )
      )
   /x
) {
   my $first = substr( ( keys( %+ ) )[0], 1 );

   ...
}

Update: Added missing ), as LanX pointed out.

[LanX]

You might want to correct this

> (?:

[tybalt89]

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11167676
use warnings;

local $_ = 'AB ABDA DCACCB AAA BSAA CAAB ACS ABA DBA BA DASSABACA A';

my $first = /(BA[ABC]{2})|(CA[CD]{2})|DA[SC]{2}/ ? $1 ? 1 : $2 ? 2 : 3
+ : 0;
print "first is $first\n";

Outputs:

first is 2