XP is just a number PerlMonks

### Re^2: Golf: Buying with exact change

by tilly (Archbishop)
 on Feb 25, 2005 at 05:25 UTC ( #434370=note: print w/replies, xml ) Need Help??

I find this claim slightly bizarre. I downloaded the PDF and read Wilf's description of the problem (he's looking for a number 1 bigger than the largest function described above). The following fairly obvious code solves the problem for arbitrary M in worst case time proportional to O(M*n*n) where n is the size of the smallest denomination. (If there are only 2 denominations then this will be O(M*n).)
```#! /usr/bin/perl -w
use strict;

print largest(@ARGV)."\n";

sub largest {
# Everything works mod \$least
my \$least = min(@_);
# We start off not knowing how to do anything.
my @first = map {undef} 1..\$least;
# For technical reasons this needs to be 0 now,
# and \$least later.
\$first[0] = 0;
for my \$num (@_) {
my @in_process = grep {defined(\$first[\$_])} 0..(\$least - 1);
while (@in_process) {
my \$to_process = shift @in_process;
my \$value = \$first[\$to_process] + \$num;
my \$mod = \$value % \$least;
if (not defined(\$first[\$mod]) or \$value < \$first[\$mod]) {
\$first[\$mod] = \$value;
print "  \$value = \$mod (mod \$least)\n";
push @in_process, \$mod;
}
}
}
\$first[0] = \$least;
if (grep {not defined(\$_)} @first) {
# We didn't reach one...
return undef;
}
else {
my \$worst = max(@first);
return \$worst - \$least;
}
}

sub min {
my \$min = shift;
for (@_) {
\$min = \$_ if \$_ < \$min;
}
return \$min;
}

sub max {
my \$max = shift;
for (@_) {
\$max = \$_ if \$_ > \$max;
}
return \$max;
}
I can only guess that he's measuring complexity in terms of the number of bits required to represent the numbers in the denomination. So he'd consider my solution as taking exponential time.

Create A New User
Node Status?
node history
Node Type: note [id://434370]
help
Chatterbox?
 [erix]: ah! Those germans again! ... they have a lot to answer for ;-)

How do I use this? | Other CB clients
Other Users?
Others drinking their drinks and smoking their pipes about the Monastery: (8)
As of 2018-06-19 09:04 GMT
Sections?
Information?
Find Nodes?
Leftovers?
Voting Booth?
Should cpanminus be part of the standard Perl release?

Results (111 votes). Check out past polls.

Notices?