perl's grep function with '^' and '$'

[jesuashok]

Fantasy monks,

Apologies If this has been discussed already,

# Program : 1
#!/usr/bin/perl

use strict;

my $match = 'A';

my @array = qq[Anthony Mark Alex A];
if ( grep( /^$match/,@array ) ) {
   print "Matched\n";
}

Output :
Matched

# Program : 2
#!/usr/bin/perl

use strict;

my $match = 'A';

my @array = qq[Anthony Mark Alex A];
if ( grep( /$match$/,@array ) ) {
   print "Matched\n";
}
<code>
Output :
Matched

# Program : 3
#!/usr/bin/perl

use strict;

my $match = 'A';

my @array = qq[Anthony Mark Alex A];
if ( grep( /^$match$/,@array ) ) {
   print "Matched\n";
}

What is the problem with the 3rd program ? am I missing something there ?

[shmem]

Try:

perl -le 'my @array = qq[Anthony Mark Alex A]; print for @array'

See? What does the qq[] operator do? you want qw[].

You would have spotted that had you written e.g.

# Program : 2
#!/usr/bin/perl

use strict;

my $match = 'A';

my @array = qq[Anthony Mark Alex A];
if ( my @list = grep( /$match$/,@array ) ) {
   print "Matched: ".join(', ', map {"'$_'"} @list)."\n";
}
__END__
Matched: 'Anthony Mark Alex A'

learn to debug... ;-)

[clinton]

Indeed you are, you should be using qw not qq. See perlop

# Program : 3
#!/usr/bin/perl

use strict;

my $match = 'A';

my @array = qw[Anthony Mark Alex A];
if ( grep( /^$match$/,@array ) ) {
   print "Matched\n";
}

[moritz]

The problem is in the quoting. qq[...] quotes a string, so your array has just one element - that happens to start with an A.

use qw(Anthony Mark Alex A) and all is fine.