how do I print all the code while executing, like in the movies?

[chuckd]

How do I print code out to sdout like in the movies? I want to see my code running on the screen.

[jasonk]

This should do it pretty much exactly the way they do it in the movies...

#!/usr/local/bin/perl -w
##################
use strict;
use warnings;
use PPI;
use Term::ANSIColor qw( colored );
$| = 1;

my @files = values %INC;
while ( time - $^T < 5 ) {
    my $doc = PPI::Document->new(
        splice( @files, rand( @files ), 1 )
    );
    $doc->prune( $_ ) for qw(
        PPI::Token::Pod PPI::Token::Comment
        PPI::Statement::Data PPI::Statement::End
        PPI::Statement::Include
    );
    my @lines = split( "\n", $doc->serialize );
    for ( splice( @lines, rand( @lines ), rand( 25 ) ) ) {
        next unless /\S/; 
        next if /^\s*1;\s*$/;
        print "$_\n";
        select( undef, undef, undef, 0.05 );
    }   
}   
print " " x 20, colored(
    [qw( bold red blink )],
    "     SECURITY PROTOCOLS BYPASSED, ACCESS GRANTED\n"
);

[ikegami]

Add

# Load ANSI driver if running in Windows.
use if $^O eq 'MSWin32', 'Win32::Console::ANSI';

and it becomes portable.

[ig]

Devel::Trace prints perl statements as they execute, but I'm not sure about the movies.

[ikegami]

Movies just print the code from top to bottom, not "as it executes".

#!/usr/bin/perl

use strict;
use warnings;

use Time::HiRes qw( sleep );

seek(DATA, 0, 0);
while (<DATA>) {
   print;
   sleep(0.150) if !eof(DATA);
}

print("Hello World!\n");

__END__

If you just want reams of computer gibberish, just download and build Perl. For lesser amounts, using the cpan tool to install just about any module should do.