Re: XML::Simple - Invalid file content

[ELISHEVA]

To avoid dying, surround the call to XMLin with an eval statement like this:

my $ref;
eval {
  $ref = $x->XMLin(...);
  print STDERR "\nHash dump:\n";
  print STDERR Dumper($ref);

  # this only returns from the eval, not the function
  #make sure we only end up in ... or do {...} if we are dying
  return 1;
} or do {
  #sometimes you can die but $@ is '' or undefined!!!
  my $err=$@
     || "Something bad happened, but I don't know what!";
  print STDERR "Invalid content in file: $@";
}

The above code has one problem though. If you have a lot of things you are going to do with $ref, you'll probably want to halt processing whenever you see a problem. Also if you put too much code in eval {...} you might have things that die and aren't due to invalid content, but rather to something you did with valid content after you put it in the XML file. You might prefer something like this:

sub processContent {
  # do initial processing ...

  my $ref;
  eval {
    $ref = $x->XMLin(...);
    return 1;  #return from eval only
  } or do {
    my $err=$@
       || "Something bad happened, but I don't know what!";
    print STDERR "Invalid content in file: $@";
    # doesn't make sense to continue
    # in a do {...}, this returns from the enclosing *subroutine*
    return 0;  #FAILURE!!!
  }
  print STDERR "\nHash dump:\n";
  print STDERR Dumper($ref);

  # do other stuff with $ref (surrounding individual statements
  # with eval {...} or do {...} as needed ....
  return 1; #SUCCESS!
}

Note: I changed your output stream to STDERR. In almost all cases it is better to send error messages to STDERR rather than STDOUT (print "some string" sends output to STDOUT). That way you can keep your "real output" separate from your logging, debugging and error messages.

Best, beth