Killing a shell script from within a perl script

[strider88]

I have a perl script that repeatedly runs a shell script within a while loop, as

LOOP1:while($run_count<max) {
 $shell_out = system("./sh1.sh");
 $run_count++;
}

Sometimes the shell script takes more time than it is supposed to take(say 10 min), during when I would like to stop the shell script and skip to the next iteration. Could you please tell me how I can achieve this ?

[jettero]

use fork, exec, alarm, and kill ... or maybe check out POE.

IPC::Open2 and IPC::Open3 may help do the job as well.

[strider88]

I tried doing this:

eval {
 local $SIG{ALRM}=sub{die "alarm\n"};
 alarm 600;
 $shell_out = system("./sh1.sh");
 alarm 0;
};
if($@) {
 die unless $@ eq "alarm\n";
}

It turns out that the shell script is not even executed.

[almut]

The problem with this code is that the shell script isn't being killed.

alarm just arranges for a signal to be delivered to the Perl process, upon which the signal handler throws an exception (die "alarm\n") which in turn causes the Perl script to continue after the eval {} block. The shell script doesn't know anything of this and happily keeps running.

It turns out that the shell script is not even executed.

This is most likely an unrelated problem. Makes me wonder how/why it did run before with the identical system command...

[almut]

You could use open with a pipe in order to get the PID of the child process, and kill it if it doesn't finish in time. Something like this:

#!/usr/bin/perl

my $pid = open my $fh, "your_command ... |" or die $!;

eval {
    local $SIG{ALRM} = sub { die "alarm\n" };
    alarm 600;
    # ... optionally read any output from the subprocess
    # while (<$fh>) { ... }
    close $fh;   # waits for child
    alarm 0;
};
if ($@ eq "alarm\n") {  # timed out
    kill 9, $pid;
}

Note that if the shell script itself is running further child processes (not that unlikely...), they would not necessarily be killed, too (depends on the behavior/setup of the shell). In that case you'd have to create a process group and kill the entire group in case of timeout. See Re^2: Killing children's of children for sample code.

[strider88]

I tried this method, but the shell script is not even executed. Why do you think this is happening?

[BrowserUk]

#! perl -slw
use strict;
use threads;
use threads::shared;

my( $max, $run_count ) = 5;
LOOP1:while( $run_count < $max ) {
    my $end = time() + 10 * 60;
    my $pid :shared;
    async {
        $pid = open SHELL, qq[| ./sh1.sh]  or die $!;
    }->detach;
    sleep 1 until $pid;
    sleep 1 while kill 0, $pid and time() < $end;
    kill 9, $pid;
    $run_count++;
}

[walto]

An (Linux) approach without threads (not tested):

LOOP1:while($run_count<max) {

my $pid = `pidof sh1.sh`;

unless ($pid eq ''){
    print "Killing Process sh1.sh PID=$pid\n";
    kill $pid;
    sleep 1;
    next;
}

else {
 $shell_out = system("./sh1.sh");
 $run_count++;
}
}