Read the Dumper data back to a hash.

[rachitmohta11]

I have a hash output stored in a Dumper file. The content looks like this. Its actually a dynamic hash.

$VAR1 = 'ASD';
$VAR2 = {};
$VAR3 = 'asdf';
$VAR4 = {
          'slkfdh' => {
                        'aslkfd' => {}
                      }
        };

How can i read this data into a hash in my script?

[moritz]

Don't dump the hash as

print Dumper %hash;

But rather use

print Dumper \%hash;
#            ^

Then you can simply use eval to obtain a hash reference, so for example

my %copied_hash = %{ eval $string };

[rachitmohta11]

What is $string in eval $string? Is it the file handle?

[ikegami]

The string returned by Dumper.

[CountZero]

Has the age-old art of reading the documentation indeed finally been lost?

From the docs of Data::Dumper:

Given a list of scalars or reference variables, writes out their contents in perl syntax. The references can also be objects. The content of each variable is output in a single Perl statement. Handles self-referential structures correctly.

The return value can be evaled to get back an identical copy of the original reference structure.

And see also the example in the Synopsis.

[kejohm]

I prefer to use the Data::Dump module, since it has a simpler interface and it doesn't try to set any variables, which makes it more convenient to use in most cases. Here is a sample of writing a structure to a file and reading it back again using Data::Dump:

#!perl
use strict;
use warnings;

use Data::Dump qw(dump);

# Create a complex structure
my %hash = (
    number => 42,
    string => 'This is a string',
    array  => [ 1 .. 10 ],
    hash   => { apple => 'red', banana => 'yellow' },
);
# See what it looks like
print "Here is the structure before dumping to file:\n";
dump \%hash;

# Print structure to file
open my $out, '>', 'dump_struct' or die $!;
print {$out} dump \%hash;
close $out;

# Read structure back in again
open my $in, '<', 'dump_struct' or die $!;
my $data;
{
    local $/;    # slurp mode
    $data = eval <$in>;
}
close $in;
# See what the structure read in looks like
print "Here is the structure after reading from file:\n";
dump $data;
__END__

[Anonymous Monk]

string-eval isn't the greatest way to undumper a Data::Dumper-ed structure , it safer to use Undumper/ Data::Undump

or even Safe->reval( Data::Dump::pp( \@foo ) )