AoHoAoH... am I delusional?

[jaydstein]

I'm still getting acquainted with perl datastructures. I have a working structure for storing my data... but it is UGLY and BULKY. I'm sure there is a better way to do this... someone please slap me across the face and show me the error of my ways.

Note... the order in which the data is accessed is important! It is also my preference to preserve the key-value relationship between the data if at all possible.

my @fooFeatures = (
    { 'Baked Goods' => [ { 'Cookies' => ['Chocolate Chip', 'Oreo'] }, 
    ]},
    { 'Fruits'      => [ { 'Apples'  => ['Fuji', 'Granny Smith'] }, 
                         { 'Oranges' => ['Tangerine', 'Navel'] }, 
    ]},
);
    
for my $fooSet ( @fooFeatures ) {
    while (my ($key, $value) = each(%$fooSet)) {
        for my $hash ( @{$value} ) {
            while (my ($k, $v) = each(%$hash)) {
                for my $feature ( @{$v} ) {
                    print "($k, $feature)<br>";
                }
            }
        }
    }
}

[NetWallah]

Assuming your problem is with the ugliness of the structure, and complexity of data entry, YAML may help.

Here is code that reverses what your code does:

use strict;
use warnings;
use YAML;
use Data::Dumper;

my $stuff = <<YAML;
---
Baked Goods:
  - Cookies:
      - Chocolate Chip
      - Oreo

Fruits:
  - Apples:
      - Fuji
      - Granny Smith
  - Oranges:
      - Tangerine
      - Navel
YAML

my $perl_structure = Load $stuff;

print Dumper \$perl_structure;

this prints:

$VAR1 = \{
            'Baked Goods' => [
                               {
                                 'Cookies' => [
                                                'Chocolate Chip',
                                                'Oreo'
                                              ]
                               }
                             ],
            'Fruits' => [
                          {
                            'Apples' => [
                                          'Fuji',
                                          'Granny Smith'
                                        ]
                          },
                          {
                            'Oranges' => [
                                           'Tangerine',
                                           'Navel'
                                         ]
                          }
                        ]
          };

Update: You can use recursive printing to step through the structure, such as the code below:

printit ($perl_structure);

sub printit{
  my $this = shift;
  if (ref $this eq ""){
     print " $this ";
     return;
  }
  for my $k (keys %$this){
     print "$k\t:";
     printit($_) for @{$this->{$k}};
     print "\n";
  }
  print "\n";
}

[planetscape]

You may find How can I visualize my complex data structure? helpful.

[VinsWorldcom]

Perl has several modules under the DBI / DBD namespace to interface with all sorts of databases. Looking at your previous posts, I still can't determine what problem you're trying to solve, but it seems like highly structured data is part of it and that - to me - means a database. Perl is more than capable of scripting information to and from your choice of database.

Pick a database - mysql for Linux, MS Access on Windows, whatever; create the schema, put your data in and let Perl pull it out (or populate) with SQL statements.

[BrowserUk]

Note... the order in which the data is accessed is important!

What defines the order of the data?

[tobyink]

Drop the extra arrays you're currently using to preserve order, and then use Tie::IxHash.

[jhourcle]

I agree, but trying to tie nested elementss can be a little bit of a pain. I'd recommend anyone considering this to read Preserving order for nested hashes using Tie::IxHash.

[lutok]

Tinkering a bit with the code in the original post

use strict;
use warnings;

my @fooFeatures = (
    { 'Baked Goods' => [ { 'Cookies' => ['Chocolate Chip', 'Oreo'] }, 
    ]},
    { 'Fruits'      => [ { 'Apples'  => ['Fuji', 'Granny Smith'] }, 
                         { 'Oranges' => ['Tangerine', 'Navel'] }, 
    ]},
);
    
for my $fooSet ( @fooFeatures ) {
    while (my ($key, $value) = each(%$fooSet)) {
        for my $hash ( @{$value} ) {
            while (my ($k, $v) = each(%$hash)) {
                for my $feature ( @{$v} ) {
                    print "$key => ( $k, $feature)\n";
                }
            }
        }
    }
}

prints out:

Baked Goods => ( Cookies, Chocolate Chip)
Baked Goods => ( Cookies, Oreo)
Fruits => ( Apples, Fuji)
Fruits => ( Apples, Granny Smith)
Fruits => ( Oranges, Tangerine)
Fruits => ( Oranges, Navel)