How do I make a hash of arrays?

[vroom]

How do I make a hash of arrays?

Originally posted as a Categorized Question.

[chromatic]

my %dramatis_personae = (
    humans => [ 'hamnet', 'shakespeare', 'robyn', ],
    faeries => [ 'oberon', 'titania', 'puck', ],
    other => [ 'morpheus, lord of dreams' ],
);

Access it like this:

foreach my $group (keys %dramatis_personae) {
    print "The members of $group are\n";
    foreach (@{$dramatis_personae{$group}}) {
        print "\t$_\n";
    }
}

[Anonymous Monk]

You can always...


push(@{$hash{$key}}, $insert_val);


...to load the arrays in the hash. That way you don't have to build the arrays, then dereference them into the hash.

[Anonymous Monk]

my @arrayOne = 1..10;
my @arrayTwo = 20..30;
my %HashOfArrays = ( one => \@arrayOne );
$HashOfArrays{two} = \@arrayTwo;
$HashOfArrays{IpointToTheSameArrayAsOne} = \@arrayOne ;
$HashOfArrays{IreferenceTheSameArrayAsOne} = \@arrayOne ;
$HashOfArrays{MyValueIsThatOfOneAsWell} = \@arrayOne ;

## to create an array reference, just type \@array
## or [ @array ]
##  [ @array ] does not equal \@array
## see perlref for more info

[Doraemon]

my $array = [];    #create new anonymous array ref
push (@$array, '11');
push (@$array, '12');
push (@$array, '13');
$hash{'first'} = $array;   # add

$array = [];   #create a new anon-array
push (@$array, '21');
push (@$array, '22');
push (@$array, '23');
$hash{'second'} = $array;  # add

print "Hash content\n";
foreach $k (keys %hash) {
   foreach (@{$hash{$k}}) {
      print " : $_";
   }
   print "\n";
}