Re^3: Untillian Headache or about the semantic of until

[BrowserUk]

Oddly enough, the $wheel < 0 may be unnecessary

Indeed.

When I originally posted my suggestion, it was purely on the basis of reading the code snippet in the OP. In general, when doing this kind of iteration with a while loop, I check the range of the index before attempting to use it to access the array.

Only after discipulus refuted the idea, did I download the snippet and play with it and found that as posted, it "worked okay".

It took a little more investigation to understand that it gets away with it because of perl's propensity to accept negative array indices.

The funny thing is, that in one way, coding it "wrongly" has a benefit:

#! perl -slw
use strict;

sub incOdo {
    my @odo = @_;
    my $wheel = $#odo;

#    until( $wheel < 0 || $odo[ $wheel ] < 9  ) {
    until( $odo[ $wheel ] < 9 || $wheel < 0  ) {
        $odo[ $wheel ] = 0;
        $wheel--;
    }
    if( $wheel < 0 ) {
        return;
    }
    else {
        $odo[ $wheel ]++;
        return @odo;
    }
}

my @odo = (0) x 2;

for( 1 .. 102 ) {
    print join '', @odo = incOdo( @odo );
}

• Coded 'correctly' attempts to iterate beyond the scale of the odometer fail silently:

  1
  2
  3
  ...
  97
  98
  99
  

• But coded 'wrongly', that beyond range attempt fails noisely:

  1
  2
  3
  ...
  98
  99
  
  Use of uninitialized value within @odo in numeric lt (<) at C:\test\ju
  +nk31.pl line 9.
  
  Use of uninitialized value within @odo in numeric lt (<) at C:\test\ju
  +nk31.pl line 9.
  

  which could be seen as an advantage :)

  Of course, there are better ways of detecting the failure...