RE: Disable animated GIFs and blinking text in Netscape

[japhy]

Several suggestions:

• The -s switch to Perl allows you to use simple options at the command-line:

  % perl -s -e 'print $A, $B' -- -A -B=hello
  1hello
  

• Don't call perl from perl unless you have a good reason to. If you want to emulate Perl's in-place editing, then do so.

Here's my offering:

#!/usr/bin/perl -spi

use strict;
use vars qw( $gif $blink );

my $files;

BEGIN {
  unless ((defined $gif or defined $blink) and @ARGV) {
    (my $exec = $0) =~ s!.*/!!;
    exit warn "usage: $exec [ -gif=[1|0] ] [ -blink=[1|0] ] files...\n
+";
  }
  $files = "@ARGV";
}

if (defined $gif) {
  if ($gif) { s/ANIMEXTZ1\.0/ANIMEXTS1.0/, s/NOTSCAPE2\.0/NETSCAPE2.0/
+ }
  else { s/ANIMEXTS1\.0/ANIMEXTZ1.0/, s/NETSCAPE2\.0/NOTSCAPE2.0/ }
}   
    
if (defined $blink) {
  if ($blink) { s/blynk/blink/ }
  else { s/blink/blynk/ }
}
 
END {
  printf "Animated GIFs are %sabled in $files\n",
    ("dis","en")[$gif] if defined $gif;
  printf "Blinking text is %sabled in $files\n",
     ("dis","en")[$blink] if defined $blink;
}

I'll comment on (or explain) the code as requested.

$_="goto+F.print+chop;\n=yhpaj";F1:eval