List of loaded subroutines

[slloyd]

I am trying to figure out a way to print the list of subroutines that are loaded via use and require of the currently running script. Is this possible?

use strict;
use Win32;
require '/mysubs.pl';
# print a list of subroutines that are currently loaded
???

[davido]

You could try the B::Xref module:

perl -MO=Xref myscript.pl

For non-trivial scripts the output can be quite verbose. Fortunately, the POD for the module mentions the -o option which allows you to dump the output to a file instead of the screen.

[xdg]

You can look at the symbol table of a package for code entries. E.g. for "main"

no strict 'refs';
for ( keys %{"main::"} ) {
  print "$_\n" if defined *{"main::$_"}{CODE};
}

If you want to know subroutines of everything loaded, then you can use the %INC hash, convert back to module names, and search through all of them for subroutines:

my @subs;
for my $mod ( keys %INC ) {
    $mod =~ s!/!::!g;
    $mod =~ s/.pm$/::/;
    {
        no strict 'refs';
        for ( keys %{$mod} ) {
            push @subs, $mod . $_ if defined *{$mod . $_}{CODE};
        }
    }
}
print "$_\n" for @subs;

(Note that this won't find subroutines that are explicitely loaded into a package that isn't named the same as the file that was required or used.)

[slloyd]

Thanks This worked great! Steve

[Fang]

I don't know the answer to your question, but I know someone asked for the same recently: Getting a list of sub routines.

Hope this helps.