perl oneliners

[valavanp]

I want to replace 3 instances of file path in a directory by using perl oneliner. This is the command which i gave and worked well.

perl -e 's/\/usr\/bin\/perl/\/test\/test\/test/g;s/\/ggg\/ggg\/www/\/z
+zz\/zzz\/zzz/g;s/\/jjj\/jjj\/jjj/\/aaa\/aaa\/aaa/g;' -pi *.pl

But when i include this oneliner in a separate file called script.pl i am getting compilations errors here is how i have given;

#!/usr/local/bin/perl

use strict;
use warnings;



perl -e 's/\/usr\/bin\/perl/\/test\/test\/test/g;s/\/ggg\/ggg\/www/\/z
+zz\/zzz\/zzz/g;s/\/jjj\/jjj\/jjj/\/aaa\/aaa\/aaa/g;' -pi *.pl


print "Done";

The following error occurred for me when i compile this.

syntax error at script.pl line 8, near "perl -e "
script.pl had compilation errors

Can anyone tell me where i am wrong? Thanks monks for your valuable suggestion.

[shmem]

You invoke your code as oneliner like this

perl -e 's/\/usr\/bin\/perl/\/test\/test\/test/g;s/\/ggg\/ggg\/www/\/z
+zz\/zzz\/zzz/g;s/\/jjj\/jjj\/jjj/\/aaa\/aaa\/aaa/g;' -pi *.pl

and in a script

#!/usr/local/bin/perl -pi

use strict;
use warnings;

s/\/usr\/bin\/perl/\/test\/test\/test/g;
s/\/ggg\/ggg\/www/\/zzz\/zzz\/zzz/g;
s/\/jjj\/jjj\/jjj/\/aaa\/aaa\/aaa/g;

END {
    print "Done\n";
}

with this line:

perl script.pl *.pl

update: To avoid backslashitis, you could write your s/// as, e.g., s|||:

s|/usr/bin/perl|/test/test/test|g;
s|/ggg/ggg/www|/zzz/zzz/zzz|g;
s|/jjj/jjj/jjj|/aaa/aaa/aaa|g;

--shmem

[valavanp]

Thanks shmem for your reply. It works well. But this script.pl file also gets changed. I wanted to keep this in the main directory and want to run the .pl files in the test directory. I am using suse linux os. the directory path is /main/script.pl -- Script file. /main/test/*.pl files -- perl files. In the oneliners there is an option like this $(find .-type f). How can i do this in the script file. Thanks for your reply.

[davidrw]

This case, just use the shell:

perl -i -e 's|/usr/bin/perl|/test/test/test|g;s|/ggg/ggg/www|/zzz/zzz/
+zzz|g;s|/jjj/jjj/jjj|/aaa/aaa/aaa|g; ' /main/script.pl `find /path/to
+/pl/files/ -type f`

FYI, there's File::Find in the standard perl distribution ... and i personally like File::Find::Rule

[graff]

But this script.pl file also gets changed... the directory path is /main/script.pl -- Script file. /main/test/*.pl files -- perl files.

Let's suppose you write your script file like this (I prefer using curly braces around regexes when the slash is part of the pattern or replacement):

#!/usr/bin/perl

use strict;
use warnings;

# check for valid usage (user must provide a directory path):

(@ARGV == 1 and -d $ARGV[0]) or die "Usage: $0 /path/to/scripts\n";

my $path = shift;
{
    local $/;   # set input record separator to undef (slurp-mode read
+ing)

    for my $file (<$path/*.pl>)  # use a file glob 
    {
        open( F, "<", $file ) or next;
        $_ = <F>;
        close F;
        s{/usr/bin/perl}{/test/test/test}g;
        s{/ggg/ggg/www}{/zzz/zzz/zzz}g;
        s{/jjj/jjj/jjj}{/aaa/aaa/aaa}g;
        open( F, ">", $file ) or die "$file: $!";
        print F;
        close F;
    }
}

When you put that script file in a directory other than the one that you provide as a command-line arg when you run it (or if you put it in the same directory, but give it a name that does not end in ".pl"), the script will not edit/rewrite itself.