Re^6: why need my in a foreach loop? (Aliasing)

[LanX]

Hi Gabor

>However I'd be interested to know in what case would you really want to write such code?

As already said my is much younger than foreach and it's consistent and backward compatible.

While looping over localized globals could also be done with an extra local $packvar=$lex_for_var, the aliasing effect of foreach can't be achieved in any other way in core Perl.

$\="\n";
 
our $foo;
 
sub f { $foo++ }
 
my ($a,$b,$c)=(0)x3;
 
 
for $foo ($a,$b,$c) {
  f();                  # increments $a,$b,$c
}
print ($a,$b,$c);       #: 111
 
 
for my $foo ($a,$b,$c) {
  f();                  # nada
}
print ($a,$b,$c);       #:  111
 
for my $x ($a,$b,$c) {
  local $foo=$x;
  f();                  # nada
}
print ($a,$b,$c);       #:  111
 
 
 
{
  my $foo;
  sub g { $foo++ }
  
  for $foo ($a,$b,$c) {
    g();                # nada (irritatingly)
  }
  print ($a,$b,$c);     #:  111
}

For a detailed discussion, see How do closures and variable scope (my,our,local) interact in perl?.

UPDATE: expanded code, fixed typos