Re: Small troubles with references

[wfsp]

Hi coldmiser!

I agree with you, references can be tricky beasties to get the hang of.

You successfully passed refs to your sub and de-referenced them. That's half the battle won already!

But you can, in fact, pass an array or a hash to a sub. Change your test script to test it.

The problem arises when, say, you want to pass two arrays.

pass_arrays(@array_one, @array_two);

sub pass_arrays{
  my @a1 = @_;
  my @a2 = @_;
}

Perl will 'flatten' both arrays into one array and copy it into @a1. @a2 will be empty. If you pass refs:

pass_arrays(\@array_one, \@array_two);

sub pass_arrays{
  my ($a1ref, $a2ref) = @_;
}

$a1ref and $a2ref now contain the refs you passed and you can use them as you did in your snippet.

You might also write a script that changes the array/hash passed into a sub and then look at what they look like after the sub has been called.

Your snippet also raises the question of scoping (as duff mentions). Have a look at Coping with Scoping to get more of an idea of what going on.

You're nearly there, good luck!

[injunjoel]

Greetings,
Just to help illustrate how Perl 'flattens' or as I try to think of it (thanks to diotalevi) 'list-ifies' subroutine arguments consider the following

#!/usr/bin/perl -w
use strict;

my @array = qw(arrayval1 arrayval2 arrayval3 arrayval4 arrayval5);
my %hash = (key1=>'val1', key2=>'val2', key3=>'val3');

sub check_input_list
{
    print "\n";
    print "@_";
    print "\n";
}

check_input_list(@array, %hash);
check_input_list(\@array, %hash);
check_input_list(@array, \%hash);
check_input_list(\@array, \%hash);

The Output

arrayval1 arrayval2 arrayval3 arrayval4 arrayval5 key2 val2 key1 val1 
+key3 val3

ARRAY(0x1824320) key2 val2 key1 val1 key3 val3

arrayval1 arrayval2 arrayval3 arrayval4 arrayval5 HASH(0x182435c)

ARRAY(0x1824320) HASH(0x182435c)

Notice in the output of the first call the keys and values from %hash get tacked onto the end of the values in @array as if the entire thing were one huge list. Now imagine trying to get keys or values from %hash? Not likely nor easy.
In the second and third examples we pass one reference but the argument list is still just a list.
The final example is much cleaner. If you were confused about what you originally passed into the sub your could always call ref and find out; otherwise there is no way to tell if you are passed a 'list-ified' hash or array.

-InjunJoel