Re: selecting from a number of different input sources.

[Khen1950fx]

IO::BufferedSelect might work for you. It was designed to work on lines rather than characters or bytes. This worked for me.

#!/usr/bin/perl

use strict;
use warnings;
use IO::BufferedSelect;

my $fh1;
my $fh2;

my $bs = new IO::BufferedSelect($fh1, $fh2);
while(1)
{
    my @canBeRead = $bs->read_line();
    foreach (@canBeRead) 
    { 
        my ($fh, $line) = @$_;
        my $fh_name = ($fh == $fh1 ? "fh1" : "fh2");
        print "fh_name: $line\n";
    }
}

[almut]

... This worked for me.

Really?  It doesn't for me — at least not with the file handles being opened to regular text files.

Buffering is only one of the problems here. The deeper issue is that with respect to select, regular disk files are defined to always be readable (even though the operation might block for a few milliseconds until the read head of the disk is positioned). In other words, if the file pointer is at the end of the file, select would still indicate that the file is readable. And because ->getline() reads until the next newline or eof, you could get partial lines (not terminated by a newline).

So, while the following sort of works, it doesn't fulfill the OP's requirement to read entire lines.

#!/usr/bin/perl
use strict;
use warnings;
use IO::Handle;
use IO::Select;

my ($fname1, $fname2) = qw(1.txt 2.txt);
open my $fh1, $fname1 or die $!;
open my $fh2, $fname2 or die $!;

my $slct = IO::Select->new();
$slct->add($fh1, $fh2);

while (1) {
    my @canBeRead = $slct->can_read(); 
    foreach my $fh (@canBeRead) { 
        my $line = $fh->getline();
        if (defined $line) {
            my $fname = $fh == $fh1 ? $fname1 : $fname2;
            print "$fname: $line\n"
        } else {
            sleep 1;  # be nice
        }
    }
}

It's effectively the same as

use IO::Handle;

my ($fname1, $fname2) = qw(1.txt 2.txt);
open my $fh1, $fname1 or die $!;
open my $fh2, $fname2 or die $!;

while (1) {
    foreach my $fh ($fh1, $fh2) { 
        my $line = $fh->getline();
        if (defined $line) {
            my $fname = $fh == $fh1 ? $fname1 : $fname2;
            print "$fname: $line\n"
        } else {
            sleep 1;  # be nice
        }
    }
}