import doesn't work at runtime?

[gdave]

so it seems I can only import() from MyModule at compile time ('use' or BEGIN') but not at runtime. Here's my test case:

my module (MyModule.pm):

package MyModule;
use Exporter();
our @ISA = qw(Exporter);
@EXPORT_OK = qw(munge frobnicate);

sub frobnicate { print "frobnicated!\n"; }
sub munge      { print "munged!\n"; }

When I call it from a script, this works (meaning I see the output from the print statements):

use MyModule qw(frobnicate munge);
frobnicate;
munge;

output is:

frobnicated!
munged!

and this works (same output)

BEGIN {
   require MyModule;
   MyModule->import( qw(frobnicate munge) );
}
frobnicate;
munge;

but this does not (no output)

require MyModule;
MyModule->import( qw(frobnicate munge) );
frobnicate;
munge;

This seems to me to imply that I can only import at compile time, not at run-time.

Am I missing something?

[johnny_carlos]

It works for me when adding parens to the subroutines:

require MyModule;
MyModule->import( qw(frobnicate munge) );
frobnicate();
munge();

[gdave]

aha! &frobnicate and &munge also do the trick. I think I get it now, thanks.

[TomDLux]

Yes, part of the consequence of having & is to identify a word as being a function name. However, there are other consequences. If you don't know what those consequences are, avoid using &.

[CountZero]

In perldoc perlsub we read:

A subroutine may be called using an explicit & prefix. The & is optional in modern Perl, as are parentheses if the subroutine has been predeclared.

So, unless you have predeclared your subs, you cannot call a sub without the parentheses. A non-predeclared sub without parentheses is just a bareword.

[bluescreen]

if you turn on use strict; and use warnings; you will realize that at compile time the interpreter complains that frobnicate and munge are not defined, coz they haven't been exported yet and the compiler doesn't know what they mean

[Perlbotics]

You're missing some parenthesis and some strictures to explain the problem. Without parens:

perl -e 'use strict; use warnings; require MyModule; MyModule->import(
+qw(frobnicate munge));  frobnicate; munge; '
Bareword "frobnicate" not allowed while "strict subs" in use at -e lin
+e 1.
Bareword "munge" not allowed while "strict subs" in use at -e line 1.
Execution of -e aborted due to compilation errors.

With:

perl -e 'use strict; use warnings; require MyModule; MyModule->import(
+qw(frobnicate munge));  frobnicate(); munge(); '
frobnicated!
munged!

With parens, Perl knows at compile time that frobnicate()/munge() are subroutines and that Perl can deal with them later at runtime. So, the following also works, but changes the semantics a bit (first argument is "MyModule") - Perl still detects the subroutine invocation (w/o parens):

perl -e 'use strict; use warnings; require MyModule; MyModule->import(
+qw(frobnicate munge));  MyModule->frobnicate; MyModule->munge; '
frobnicated!
munged!