Re: Dynamic re-pack widget

[thundergnat]

Since you don't show any code, it is difficult to point out where you might need to make changes to accomplish your goal. That being said... I don't think your issue is the form geometry manager particularly. If it works as you expect when you use the slider to adjust it, then it should also work if you set it using the built in $scale->set() method. That will fire any attached command routines. See demo below. Note that the tied variable $w{size} holds the value of the scale. If you change $w{size} directly, it won't fire the command. You need to use $w{scale}->set.

use warnings;
use strict;
use Tk;

my %w;

$w{size} = 90;

$w{mw} = MainWindow->new;

$w{mw}->Label( -text => 'Let it snow!' )->pack;

$w{frame} = $w{mw}->Frame(-borderwidth => 10)->pack;

$w{scale} = $w{frame}->Scale(qw/-orient vertical -length 284 -from 120
+ -to 10 /,
    -command => sub { $w{label}->configure( -font => "{Arial} $w{size}
+") },
    -variable => \$w{size}
)->pack(-side =>'left');

$w{label} = $w{frame}->Label(
    -text => "\x{2603}",
    -font => "{Arial} $w{size}"
)->pack(-side =>'right');

$w{frame}->Button(
   -text => "${_}pt.",
   -width => 4,
   -command => [ sub { $w{scale}->set($_[0]) }, $_ ]
)->pack() for qw/20 40 60 80 120/;

MainLoop;

For a contrast, change the button command to:

[ sub { $w{size} = $_[0] }, $_ ]