Re^3: How to add columns with new row name using perl from mysql query?

[Anonymous Monk]

There are two fast ordered-hash implementationson on CPAN: Hash::Ordered and MCE::Shared::Ordhash.

use strict;
use warnings;

use Hash::Ordered;
use Data::Dumper;

tie my %table, 'Hash::Ordered';

for my $key (qw( a_a b_b c_c d_d e_e )) {
   $table{$key}{'pend'} += 1;
   $table{$key}{'run'}  += 2;
}

print Dumper(\%table), "\n";

The following does the same thing via MCE::Shared::Ordhash (non-shared construction via Tie).

use strict;
use warnings;

use MCE::Shared::Ordhash;
use Data::Dumper;

tie my %table, 'MCE::Shared::Ordhash';

for my $key (qw( a_a b_b c_c d_d e_e )) {
   $table{$key}{'pend'} += 1;
   $table{$key}{'run'}  += 2;
}

print Dumper(\%table), "\n";

Both produce the following output. Notice how the first level keys have retained order.

$VAR1 = {
          'a_a' => {
                     'run' => 2,
                     'pend' => 1
                   },
          'b_b' => {
                     'pend' => 1,
                     'run' => 2
                   },
          'c_c' => {
                     'run' => 2,
                     'pend' => 1
                   },
          'd_d' => {
                     'run' => 2,
                     'pend' => 1
                   },
          'e_e' => {
                     'run' => 2,
                     'pend' => 1
                   }
        };

These modules are reasonably fast. The OO interface is faster when extra performance is desired. However, the TIE interface is nice when wanting the native hash look and feel. There's no reason why one cannot have both. MCE::Shared::Ordhash, via the overload mechanism, handles on-demand hash-dereferencing on the fly.

use strict;
use warnings;

use MCE::Shared::Ordhash;
use Data::Dumper;

my $table = MCE::Shared::Ordhash->new();

for my $key (qw( a_a b_b c_c d_d e_e )) {
   $table->{$key}{'pend'} += 1;
   $table->{$key}{'run'}  += 2;
}

print Dumper($table), "\n";

The table hash is the real MCE::Shared::Ordhash object and not something hidden behind the TIE interface. Therefore, a dump of it will give you the structure of the object.

$VAR1 = bless( [
                 {
                   'a_a' => {
                              'run' => 2,
                              'pend' => 1
                            },
                   'b_b' => {
                              'pend' => 1,
                              'run' => 2
                            },
                   'd_d' => {
                              'run' => 2,
                              'pend' => 1
                            },
                   'c_c' => {
                              'pend' => 1,
                              'run' => 2
                            },
                   'e_e' => {
                              'pend' => 1,
                              'run' => 2
                            }
                 },
                 [
                   'a_a',
                   'b_b',
                   'c_c',
                   'd_d',
                   'e_e'
                 ],
                 {},
                 \0,
                 \0,
                 {
                   'a_a' => $VAR1->[0]{'a_a'},
                   'b_b' => $VAR1->[0]{'b_b'},
                   'c_c' => $VAR1->[0]{'c_c'},
                   'd_d' => $VAR1->[0]{'d_d'},
                   'e_e' => $VAR1->[0]{'e_e'}
                 }
               ], 'MCE::Shared::Ordhash' );

If you have time, check them out. Do random deletes or anything pertaining to a hash. You will be pleased with the performance. In that case, one might find the following useful.

  use strict;
  use warnings;

  use Hash::Ordered;
  use MCE::Shared::Ordhash;
  use List::Util 'shuffle';
  use Time::HiRes 'time';

  my ($start, $total); srand 0;

  sub ready {
      my $time = time;
      $total  += $time - $start;
      $start   = $time;
  }

# my $oh = Hash::Ordered->new();
  my $oh = MCE::Shared::Ordhash->new();

  print ref($oh), "\n";

  my @keys1 = shuffle('aaaa'..'gggf');  # size: 109,674
  my @keys2 = shuffle('gggg'..'mmmm');  # size: 109,675
  my @keys3 = shuffle('nnnn'..'ttts');  # size: 109,674
  my @keys4 = shuffle('tttt'..'zzzz');  # size: 109,675

  $oh->set($_,$_) for ('a'..'m','_','n'..'z'); # add 26 or more keys
  $oh->delete('_');                            # has INDX afterwards

  $start = time;
  $oh->set($_,$_) for @keys1;
  printf "duration (set    ): %0.02f\n", time - $start;

  ready();
  $oh->push($_,$_) for @keys2;
  printf "duration (push   ): %0.02f\n", time - $start;

  ready();
  $oh->unshift($_,$_) for @keys3;
  printf "duration (unshift): %0.02f\n", time - $start;

  ready();
  $oh->merge(map {$_,$_} @keys4);
  printf "duration (merge  ): %0.02f\n", time - $start;

# ready();
# $oh->delete($_) for @keys2;
# printf "duration (delete ): %0.02f\n", time - $start;

  printf "total time        : %0.02f\n", $total += time - $start;

Results vary from system to system. The following were captured from a 2.6 GHz machine. Anyway, these are the fastest pure-Perl ordered-hash implementations on CPAN right now. The results show the time taken to complete each action. Thus, lower is faster.

Hash::Ordered
duration (set    ): 0.20
duration (push   ): 0.24
duration (unshift): 0.29
duration (merge  ): 0.23
total time        : 0.95

MCE::Shared::Ordhash
duration (set    ): 0.12
duration (push   ): 0.16
duration (unshift): 0.21
duration (merge  ): 0.15
total time        : 0.65

MCE::Shared::Ordhash has low overhead. The reason is that the internal INDX hash is populated only on-demand. There are no worries about delays, for example deleting keys. Compare these with Tie::IxHash. Do forward and reverse deletes. Not to forget random deletes.

Perl is fun.