How to return multiple array from subroutine

[qsl]

Helping Monks,

When i tried to return multiple array from subroutine,the two array contents are available in the first array itself.Canyou please let me know how the two arrays can be get separately.Find the below code,

sub breakEmailAddress
{
        my ($address) = shift(@_); 
        @components = split('@', $address); 
        @counter =  split('@',$address);    
        return (@components,@counter); 
}

(@first,@second) = &breakEmailAddress('[e-mail]');

print"FirstArr:@first\n";
print"SecondArr: @second\n";

It prints,

FirstArr:john some.domain.com john some.domain.com
SecondArr:

Advice me how to get the array individually.
Thanks,
qsl.

[ikegami]

You can't. Subs return a single list. You could return references to those arrays, though.

sub breakEmailAddress
{
   my ($address) = shift(@_); 
   my @components = split('@', $address); 
   my @counter    = split('@', $address);
   return (\@components, \@counter);
}

my ($first, $second) = breakEmailAddress('[e-mail]');
print "FirstArr: @$first\n";
print "SecondArr: @$second\n";

Don't forget to use my on the arrays, or else you'll always return a reference to the same arrays. Using my forces the creation of new arrays every call.

I removed the & from your subroutine call. Why are you telling Perl to ignore prototypes?

Update: Alternatively, you can pass references to your arrays to the sub, and have it fill up the arrays instead of returning values:

sub breakEmailAddress
{
   my ($components, $counter, $address) = shift(@_); 
   @$components = split('@', $address); 
   @$counter    = split('@', $address);
}

# breakEmailAddress(my @first, my @second, '[e-mail]'); XX
+X

my(@first,@second);
breakEmailAddress(\@first, \@second, '[e-mail]');  # Fixed
+ thanks to shmem

print "FirstArr: @first\n";
print "SecondArr: @second\n";

Update: Applied shmem's fix.

[shmem]

ikegami,don't submit bugs! ;-)

sub breakEmailAddress
{
   my ($components, $counter, $address) = @_;
   @$components = split('@', $address);
   @$counter    = split('@', $address);
}

my(@first,@second);
breakEmailAddress(\@first, \@second, '[e-mail]');
print "FirstArr: @first\n";
print "SecondArr: @second\n";

cheers,
--shmem

[Anonymous Monk]

"Don't forget to use my on the arrays." This helped to solve a different problem I was facing. Thanks a lot!!

[dorward]

Return an arraylist of array references. See perlref

-- update for pedants :)

[davorg]

<pedant>
You mean a _list_ of array references
</pedant>

[izut]

You have to return array references instead

use Data::Dumper;

sub function {
   my @arr_a = (1, 2, 3);
   my @arr_b = (4, 5, 6);

   return (\@arr_a, \@arr_b);
}

my ($arr_a, $arr_b) = function();
print Dumper $arr_a, $arr_b;

__END__
$VAR1 = [
          1,
          2,
          3
        ];
$VAR2 = [
          4,
          5,
          6
        ];

[madtoperl]

Hi,

If you need to return multiple array,you should return the array by reference and in the calling place you have to de-reference it and use.otherwise the boundary may be getting collapsed and the whole array contents will be available in the first array itself.The below code will work fine,


sub breakEmailAddress
{
        my ($address) = shift(@_); 
        @components = split('@', $address); 
        @counter =  split('@',$address);    
        return (\@components,\@counter); 
}

($first,$second) = &breakEmailAddress('[e-mail]');

print"FirstArr=>@$first\n";
print"SecondArr=>@$second\n";

Thanks and Regards,
madtoperl.