Parsing in perl

[Nalababu]

I need help in parsing this output:

 ENSMUSG00000027831    ENSTBEG00000008938    ortholog_one2one    Euthe
+ria    56.2942008486563    
ENSMUSG00000027831    ENSLAFG00000011038    ortholog_one2one    Euther
+ia    58.5845347313237    
ENSMUSG00000027831    ENSDORG00000014560    ortholog_one2one    Sciuro
+gnathi    43.9759036144578

and getting the value greater than 50.000 and printing that entry separately. this is my program i wrote but im getting error uninitialized value in split:

use strict;
use warnings;
use Getopt::std;
my $le = "lethal_results.txt";
open(LE , "<", $le) or die ("Unable to open file $le: $!");
my @le_data = <LE>;
my $le_data;
close (LE);
for( my$i=1; $i<= @le_data; $i++)
{
my @line = split(/\s+/,$le_data[$i]);
my $width = 11;
if(@le_data[5] >= 50.000)
{ 
my $data = $le_data[$i];
chomp $data;
printf("%s%${width}s%${width}s%\t\t%.6g\n", $le_data[1],$le_data[2],$l
+e_data[4],$le_data[6]);
}

What is wrong with the code? How can i rectify it. I am not sure with what datatype to use for each value?

[ikegami]

@le_data contains the lines of the file (which is a total waste of memory, incidentally). @line contains the fields. You never use contents of @line.

Also, your indexes make no sense. The fields are indexed 0 to 4, but you're accessing index 6.

use strict;
use warnings;

my $width = 11;

my $le = "lethal_results.txt";
open(LE , "<", $le)
   or die("Unable to open file $le: $!\n");

while (<LE>) {
   chomp;
   my @line = split(/\s+/, $_);
   if ($line[4] >= 50) {
      printf("%s%${width}s%${width}s%\t\t%.6g\n",
         @line[0,1,2,4]
      );
   }
}

[McDarren]

Hi :)

You're doing a lot of convulted stuff there with arrays and C-style loops, that really isn't necessary.

When you need to examine a file line by line, you're usually better reaching for a 'while' loop, rather than a 'for' loop.

Here is a slightly more perlish way to do what you want.

#!/usr/bin/perl
use strict;
use warnings;

my $le = 'lethal_results.txt';

open my $in, '<', $le or die "Cannot open $le:$!\n";

while (<$in>) {
    chomp;
    my $foo = (split)[4];
    print "$foo\n" if $foo >= 50;
}

close $in;

Of course, you could always just do something like:

perl -lane 'print $F[4] if $F[4] >= 50' < lethal_results.txt

Cheers,
Darren :)

[almut]

Try something like this:

...
for (@le_data) {
    my @line = split /\s+/;
    if ($line[4] >= 50.000) { 
        my $width = 11;
        printf "%s%${width}s%${width}s\t\t%.6g\n", @line[0,1,3,4];
    }
}

[arc_of_descent]

Yor are declaring $le_data which you don't need. You already have the lines in the @le_data array. In Perl, you access an array element using $array_name. Just remove the

my $le_data;

line. And in the if condition, you need to do $le_data[5]

[ambrus]

You probably want $le_data[4] instead of $le_data[5].

Update: sorry, let me try again. You probably want $line[4] instead of $le_data[5]; also change the outer for loop to go from 0 up to @le_data - 1 instead of from 1.

[Bloodnok]

2 things:
• I need help reading it - use <code> </code> tags round the output
• Normally, we say please ;-)

[wazoox]

The "uninitialized value in split" error is probably due to empty lines in your input.

[DStaal]

Try this a moment:

foreach my $val ( @le_data ) {
    my @line = split /\s+/, $val;
    my width = 11;
...

Your actual problem is that arrays are zero-indexed, not one-indexed, but the above is a much more Perlish way to loop through all the values of the array.

[Anonymous Monk]

Another way (golf anyone?)

use strict;
use warnings;

open(LE , "<", $le) or die ("Unable to open file $le: $!");
my $width=11;
while (<LE>) {
    my @line;
    printf("%s%${width}s%${width}s%\t\t%.6g\n", @line[0,1,2,4]) 
        if (@line = split) && ($line[4] gt 50);
}
close LE;

[bichonfrise74]

Another way of doing it...

#!/usr/bin/perl

use strict;

while (<DATA>) {
    print if ( (split)[4] > 50 );
}

__DATA__
ENSMUSG00000027831    ENSTBEG00000008938    ortholog_one2one    Euther
+ia    56.2942008486563
ENSMUSG00000027831    ENSLAFG00000011038    ortholog_one2one    Euther
+ia    58.5845347313237
ENSMUSG00000027831    ENSDORG00000014560    ortholog_one2one    Sciuro
+gnathi    43.9759036144578

[ikegami]

@le_data contains the lines of the file (which is a total waste of memory, incidentally). @line contains the fields. You never use contents of @line.

Also, your indexes make no sense. The fields are indexed 0 to 4, but you're accessing index 6.

use strict;
use warnings;

my $width = 11;

my $le = "lethal_results.txt";
open(LE , "<", $le)
   or die("Unable to open file $le: $!\n");

while (<LE>) {
   chomp;
   my @line = split(/\s+/, $_);
   if ($line[4] >= 50) {
      printf("%s%${width}s%${width}s%\t\t%.6g\n",
         @line[0,1,2,4]
      );
   }
}