Unique rows in Array of array

[DreamT]

Hi!
I have an array where every row is an array with three values. I want to remove the rows where the three values are equal. How do I do it? (I've looked around but can't find any solution that applies on an AoA, only on scalars in an array)

[choroba]

To filter an array one usually uses grep. You have to dereference the inner arrays to get to their members:

#!/usr/bin/perl
use warnings;
use strict;

use Data::Dumper;

my @array = ([ 1,  2,  3],
             [10, 10, 10],
             [ 1,  1,  5]);

my @nonequal = grep $_->[0] != $_->[1]
                    ||
                    $_->[2] != $_->[0],
               @array;

print Dumper \@nonequal;

[johngg]

choroba gives you a solution for the problem as you present it but, more generally, if you have arrays with longer rows the number of conditions inside the grep becomes unwieldy. A nested grep solution can overcome this.

$ perl -E '
> @arr = (
>    [ 1, 3, 6 ],
>    [ 8, 8, 8 ],
>    [ 3, 9, 0 ],
>    [ 1, 4, 5, 3, 6, 9, 4, 2 ],
>    [ 2, 2, 2, 2, 2, 2, 2 ],
>    );
> 
> @neq =
>    grep {
>       $zero = $_->[ 0 ];
>       grep { $zero != $_ } @$_[ 1 .. $#{ $_ } ]
>       } @arr;
> 
> say qq{@$_} for @neq;'
1 3 6
3 9 0
1 4 5 3 6 9 4 2

I hope this is of interest.